Fordham University

Computer calculations for "Some singular curves in Mukai's model of \(\overline{M}_7\)", Section 6

Code 6.8: Computing \( \dim (V(5\omega_1) \otimes V(5 \omega_1))^T\)

We compute \( \dim (V(5\omega_1) \otimes V(5 \omega_1))^T\). For each element \(f_i \) in a basis of \(V(5\omega_1)\), we can tensor with any basis element \(g_j\) of opposite weight to get a basis element of \( (V(5\omega_1) \otimes V(5 \omega_1))^T\). If \(f_i\) has weight \(\mu\), and the dimension of \(V(5\omega_1)_\mu\) is \(m(\mu)\), then by symmetry under the Weyl group, \(V(5\omega_1)_{-\mu}\) also has dimension \( m(\mu)\). It follows that \[ \dim (V(5\omega_1) \otimes V(5 \omega_1))^T = \sum m(\mu)^2 \] We compute this below. 
Macaulay2, version 1.20
with packages: ConwayPolynomials, Elimination, IntegralClosure, InverseSystems, Isomorphism, LLLBases,
               MinimalPrimes, OnlineLookup, PrimaryDecomposition, ReesAlgebra, Saturation, TangentCone

i1 : loadPackage("LieTypes");
 -- warning: symbol "isIsomorphic" in Isomorphism.Dictionary is shadowed by a symbol in LieTypes.Dictionary
 --   use the synonym Isomorphism$isIsomorphic

i2 : so10=simpleLieAlgebra("D",5);

i3 : V5w1 = irreducibleLieAlgebraModule({5,0,0,0,0},so10);

i4 : WD=weightDiagram(V5w1);

i5 : sum apply(keys WD, k -> (WD#k)^2)

o5 = 4722
With a little more work, we can compute the space of \(T\) and \(W\) invariants, where \(W\) is the Weyl group. Using the Weyl group, we may assume that \(f_i\) is a dominant weight. 
i6 : DomWts = select(keys WD, k -> all(k, i -> i>=0))

o6 = {{1, 0, 0, 1, 1}, {5, 0, 0, 0, 0}, {3, 1, 0, 0, 0}, {1, 2, 0, 0, 0}, {3, 0, 0, 0, 0}, {1, 1, 0, 0, 0},
     --------------------------------------------------------------------------------------------------------
     {1, 0, 0, 0, 0}, {0, 0, 0, 0, 2}, {2, 0, 1, 0, 0}, {0, 1, 1, 0, 0}, {0, 0, 0, 2, 0}, {0, 0, 1, 0, 0}}

o6 : List

i7 : MultOfDomWts = new HashTable from apply(DomWts, k -> {k,WD#k})

o7 = HashTable{{0, 0, 0, 0, 2} => 1 }
               {0, 0, 0, 2, 0} => 1
               {0, 0, 1, 0, 0} => 4
               {0, 1, 1, 0, 0} => 1
               {1, 0, 0, 0, 0} => 10
               {1, 0, 0, 1, 1} => 1
               {1, 1, 0, 0, 0} => 4
               {1, 2, 0, 0, 0} => 1
               {2, 0, 1, 0, 0} => 1
               {3, 0, 0, 0, 0} => 4
               {3, 1, 0, 0, 0} => 1
               {5, 0, 0, 0, 0} => 1

o7 : HashTable

i8 : sum apply(DomWts, k -> (WD#k)^2)

o8 = 156