Computer calculations for "Some singular curves in Mukai's model of \(\overline{M}_7\)", Section 4

Code 4.4: A linear space \(P_{\operatorname{rib}}\) such that \( P_{\operatorname{rib}} \cap OG(5,10) \) is the balanced ribbon

We show that for \(s = ([1:-1],[1:-1])\), the scheme \( P_{s} \cap OG(5,10)\) is the balanced ribbon.

We begin by repeating the calculation used in Case 1 in Code 4.3 to compute the quadrics defining \( P_{s} \cap OG(5,10)\).

i1 : S=QQ[y_0..y_6];

i2 : c_2=-1;

i3 : c_4=-1;

i4 : -- Variables used to parametrize P_s
     x_1245=y_0;

i5 : x_1345=y_1;

i6 : x_2345=y_2;

i7 : x_14=y_3;

i8 : x_15=y_4;

i9 : x_25=2*y_5;

i10 : x_35=y_6;

i11 : -- Nine equations defining the remaining variables
      x_0=0;

i12 : x_12=-c_4*x_1345;

i13 : x_13=-c_2*x_2345;

i14 : x_23=x_14;

i15 : x_24=-2*c_2*x_15;

i16 : x_34=-1/2*c_4*x_25;

i17 : x_45=0;

i18 : x_1234=0;

i19 : x_1235=0;

i20 : L = {x_0*x_2345-x_23*x_45+x_24*x_35-x_25*x_34,
      x_12*x_1345-x_13*x_1245+x_14*x_1235-x_15*x_1234,
      x_0*x_1345-x_13*x_45+x_14*x_35-x_15*x_34,
      x_12*x_2345-x_23*x_1245+x_24*x_1235-x_25*x_1234,
      x_0*x_1245-x_12*x_45+x_14*x_25-x_15*x_24,
      x_13*x_2345-x_23*x_1345+x_34*x_1235-x_35*x_1234,
      x_0*x_1235-x_12*x_35+x_13*x_25-x_15*x_23,
      x_14*x_2345-x_24*x_1345+x_34*x_1245-x_45*x_1234,
      x_0*x_1234-x_12*x_34+x_13*x_24-x_14*x_23,
      x_15*x_2345-x_25*x_1345+x_35*x_1245-x_45*x_1235};

Next, we load the equations of the canonically embedded balanced ribbon, and check that these two sets of quadrics define the same ideal.

i21 : BR7={y_2*y_3-2*y_1*y_4+y_0*y_5, y_2*y_4-2*y_1*y_5+y_0*y_6,
y_3^2-2*y_2*y_4+y_1*y_5, y_3*y_4-2*y_2*y_5+y_1*y_6, -y_1^2+y_0*y_2,
-y_1*y_2+y_0*y_3, -y_2^2+y_1*y_3, -y_4^2+y_3*y_5, -y_4*y_5+y_3*y_6,
-y_5^2+y_4*y_6};

i22 : ideal(L)==ideal(BR7)

o22 = true

In fact, more is true: the quadrics in these two sets differ only by scaling.

i23 : L = sort apply(L, f -> (1/leadCoefficient(f))*f);

i24 : BR7 = sort apply(BR7, f -> (1/leadCoefficient(f))*f);

i25 : L==BR7

o25 = true