run "date";
needsPackage("LieAlgebraRepresentations");
sl6 = simpleLieAlgebra("A",5);
rhoStd = standardRepresentation(sl6);
rhoW2Std = exteriorPower(2,rhoStd);
rhoW2Stdstar = dual rhoW2Std
-- Step 2: Get V30100 in W9W2Stdstar
V30100 = irreducibleLieAlgebraModule({3,0,1,0,0},sl6);
LAB = rhoStd#"Basis";
L30100 = GTrepresentationMatrices(V30100);
rhoV30100 = lieAlgebraRepresentation(V30100,LAB,L30100);
-- Need a hwv for V30100 in W9W2Stdstar
-- Relatively easy because the weight {3,0,1,0,0} subspace in W9W2Stdstar is one-dimensional
wts = representationWeights(rhoW2Stdstar);
s9 = subsets(apply(#wts, i -> i),9);
select(s9, s -> sum apply(s, j -> wts_j)=={3,0,1,0,0})
t = first select(s9, s -> sum apply(s, j -> wts_j)=={3,0,1,0,0});
hwv1 = transpose matrix {apply(s9, s -> if s==t then 1/1 else 0/1)};
time V30100inW9W2Stdstar = VInWedgekW(rhoV30100,9,rhoW2Stdstar,hwv1,"SaveAsFunction"=>"V30100inW9W2Stdstar");
-- Step 3: Get V03000 in Sym2 V30100
hwv2 = weightMuHighestWeightVectorsInSymdW({0,3,0,0,0},2,rhoV30100);
V03000=irreducibleLieAlgebraModule({0,3,0,0,0},sl6);
L03000 = GTrepresentationMatrices(V03000);
rhoV03000 = lieAlgebraRepresentation(V03000,LAB,L03000);
V03000inS2V30100 = VInSymdW(rhoV03000,2,rhoV30100,hwv2_0,"SaveAsFunction"=>"V03000inS2V30100");
-- Step 4: Get V00000 in Sym3 V03000
hwv3 = weightMuHighestWeightVectorsInSymdW({0,0,0,0,0},3,rhoV03000);
rhoV00000=trivialRepresentation(sl6);
rhoV00000 = lieAlgebraRepresentation(rhoV00000#"Module",LAB,rhoV00000#"RepresentationMatrices");
V00000inS3V03000 = VInSymdW(rhoV00000,3,rhoV03000,hwv3_0,"SaveAsFunction"=>"V00000inS3V03000");
run "date";