run "date";
needsPackage("LieAlgebraRepresentations");
sl6 = simpleLieAlgebra("A",5);
rhoStd = standardRepresentation(sl6);
rhoW2Std = exteriorPower(2,rhoStd);
rhoW2Stdstar = dual rhoW2Std;
-- Step 2: Get V00030 in W9W2Stdstar
V00030 = irreducibleLieAlgebraModule({0,0,0,3,0},sl6);
LAB = rhoStd#"Basis";
L00030 = GTrepresentationMatrices(V00030);
rhoV00030 = lieAlgebraRepresentation(V00030,LAB,L00030);
-- Need a hwv for V00030 in W9W2Stdstar
-- Relatively easy because the weight {0,0,0,3,0} subspace in W9W2Stdstar is one-dimensional
wts = representationWeights(rhoW2Stdstar);
s9 = subsets(apply(#wts, i -> i),9);
t = first select(s9, s -> sum apply(s, j -> wts_j)=={0,0,0,3,0})
hwv1 = transpose matrix {apply(s9, s -> if s==t then 1/1 else 0/1)};
time V00030inW9W2Stdstar = VInWedgekW(rhoV00030,9,rhoW2Stdstar,hwv1,"SaveAsFunction"=>"V00030inW9W2Stdstar");
-- Step 3: Get the invariant in Sym3 V00030
hwv2 = weightMuHighestWeightVectorsInSymdW({0,0,0,0,0},3,rhoV00030);
rhoV00000=trivialRepresentation(sl6);
rhoV00000 = lieAlgebraRepresentation(rhoV00000#"Module",LAB,rhoV00000#"RepresentationMatrices");
V00000inS3V00030 = VInSymdW(rhoV00000,3,rhoV00030,hwv2_0,"SaveAsFunction"=>"V00000inS3V00030");
run "date";