run "date";
load "InvariantPolynomialsforMukaiModels.m2";
matrixFromHyperplaneEquations = (L) -> (
    R:=ring(L_0);
    eqnMatrix:=matrix apply(L, f -> apply(numgens R, i -> coefficient(R_i,f)));
    transpose gens ker eqnMatrix
);

-- The ordering and numbering here match Theorem 4.1 in the preprint
-- Genus 7
S=QQ[x_0,x_12,x_13,x_14,x_15,x_23,x_24,x_25,x_34,x_35,x_45,x_1234,x_1235,x_1245,x_1345,x_2345];
-- Example 7a: the genus 7 tangent developable
LTD7 = {x_13, x_23+(5/3)*x_15, x_24, x_34-5*x_25, x_45-(4/3)*x_35, x_1245-(9/8)*x_1235, x_1345+(1/2)*x_12, x_2345+(2/15)*x_14};
F72(matrixFromHyperplaneEquations LTD7)
-- Example 7b: the genus 7 cuspidal cubic with 7-gonal symmetry
LCusp7 =
{x_13, x_23+(5/3)*x_15, x_24, x_34-5*x_25, x_45-(4/3)*x_35, x_1245-(9/8)*x_1235, x_1345+(1/2)*x_12, x_2345+(2/15)*x_14,x_1234-1/30*x_0};
F71(matrixFromHyperplaneEquations LCusp7)
-- Example 7c: the genus 7 balanced K3 carpet
LK3Carpet7 = {x_0, x_12-x_1345, x_13-x_2345, x_24-2*x_15, x_34-1/2*x_25, x_45, x_1234, x_1235};
F72(matrixFromHyperplaneEquations LK3Carpet7)
-- Example 7d: the genus 7 balanced ribbon
LBalRib7 = {x_0, x_12-x_1345, x_13-x_2345, x_24-2*x_15, x_34-1/2*x_25, x_45, x_1234, x_1235, x_23-x_14};
F71(matrixFromHyperplaneEquations LBalRib7)
-- Example 7e: a genus 7 graph curve
LGraphCurve7={x_2345, x_1245, x_1234, x_35, x_23-x_25, x_15+x_25-x_35-x_45, x_14, x_12-x_13, x_0+x_25-x_35-x_45};
F71(matrixFromHyperplaneEquations LGraphCurve7)



-- Genus 8
K = toField(QQ[sqrt2,Degrees=>{0}]/ideal(sqrt2^2-2));
-- The order of the variables shown here is grevlex for subsets
-- Do this to match M2's exteriorPower function
R = K[x_12,x_13,x_23,x_14,x_24,x_34,x_15,x_25,x_35,x_45,x_16,x_26,x_36,x_46,x_56];
-- Example 8a: the genus 8 tangent developable
LTD8 = {x_23-(5/3)*x_14, x_24-5*x_15, x_25-15*x_16, x_34-20*x_16, x_35-5*x_26, x_45-(5/3)*x_36};
F82(matrixFromHyperplaneEquations LTD8)
-- Example 8b: the genus 8 cuspidal cubic with 8-gonal symmetry
LCusp8 = {x_23-(5/3)*x_14, x_24-5*x_15, x_25-15*x_16, x_34-20*x_16, x_35-5*x_26, x_45-(5/3)*x_36, x_12-x_56};
F81(matrixFromHyperplaneEquations LCusp8)
-- Example 8c: a genus 8 reducible surface with four components, each generically nonreduced
LNonRedSurf8 = {x_12-x_34, x_12-x_13, x_14-x_45, x_16-x_23, x_24-x_35, x_26-x_36};
F82(matrixFromHyperplaneEquations LNonRedSurf8)
-- Example 8d: a genus 8 reducible curve with five components, each generically nonreduced:
LNonRedCurve8={x_12-x_34, x_12-x_13, x_14-x_45, x_16-x_23, x_24-x_35, x_26-x_36, x_15-x_46};
F81(matrixFromHyperplaneEquations LNonRedCurve8)
-- Example 8e: a genus 8 graph curve
LGraphCurve8 = {x_12-32*x_46, x_13+(64*sqrt2 - 96)*x_56, x_14+(1/32)*x_23, x_15-x_24, x_16+(1/32*(2*sqrt2 + 3))*x_35, x_25-x_34, x_26-x_45};
F81(matrixFromHyperplaneEquations LGraphCurve8)



-- Genus 9
-- Example 9a: the genus 9 tangent developable
K = toField(QQ[sqrt3,Degrees=>{0}]/(sqrt3^2-3));
S = K[z_0..z_13];
LTD9 = {z_3-(135/2)*z_4,z_9-(1/432)*z_10,z_5-45*z_12,z_6 + 36*z_11};
F92(matrixFromHyperplaneEquations LTD9)
-- Example 9b: the genus 9 cuspidal cubic with 9-gonal symmetry
LCusp9 = {z_3-(135/2)*z_4,z_9-(1/432)*z_10,z_5-45*z_12,z_6 + 36*z_11,z_0+1/5*z_13};
F91(matrixFromHyperplaneEquations LCusp9)
-- Example 9c: the genus 9 balanced K3 carpet
LK3Carpet9 = {z_0,z_13,z_3+1/2*z_4,z_9+1/2*z_10};
F92(matrixFromHyperplaneEquations LK3Carpet9)
-- Example 9d: the genus 9 balanced ribbon:
LBalRib9 = {z_0,z_13,z_3+1/2*z_4,z_9+1/2*z_10,z_1-4*z_7};
F91(matrixFromHyperplaneEquations LBalRib9)
-- Example 9e: a genus 9 graph curve
LGraphCurve9= {z_0-(12*sqrt3 - 18)*z_13, z_4-((4/9)*sqrt3+2/3)*z_3, z_6-(12*sqrt3-21)*z_1, z_10-(-6*sqrt3 + 9)*z_9, z_12+1/3*z_7 };
F91(matrixFromHyperplaneEquations LGraphCurve9)



-- Genus 10
S = QQ[H_1,H_2,X_1,X_2,X_3,X_4,X_5,X_6,Y_1,Y_2,Y_3,Y_4,Y_5,Y_6];
-- Example 10a: the genus 10 tangent developable
LTD10={H_1-4/9*H_2, X_3-4/27*Y_6, Y_3-5/4*X_6};
F102(matrixFromHyperplaneEquations LTD10)
-- Example 10b: the genus 10 cuspidal cubic with 10-gonal symmetry
LCusp10={H_1-4/9*H_2, X_3-4/27*Y_6, Y_3-5/4*X_6,X_5+8/75*Y_5};
F101(matrixFromHyperplaneEquations LCusp10)
-- Example 10c: a genus 10 reducible surface with two components, each generically nonreduced
LNonRedSurf10 = {X_1-Y_1,Y_2-Y_3,X_4-X_5};
F102(matrixFromHyperplaneEquations LNonRedSurf10)
-- Example 10d: a genus 10 reducible curve with three components, each generically nonreduced
LNonRedCurve10 = {X_1-Y_1,Y_2-Y_3,X_4-X_5,H_1-Y_5};
F101(matrixFromHyperplaneEquations LNonRedCurve10)
run "date";
quit